REDROOM

Create

Preview: getopt.awk Size: 2.15 KB

//usr/share/gawk/getopt.awk

# getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <c>    a character representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

    if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf("%c -- invalid option\n", thisopt) > "/dev/stderr"
        if (_opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return "?"
    }
    if (substr(options, i + 1, 1) == ":") {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) > 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = ""
    if (_opti == 0 || _opti >= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

    # test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, "ab:cd")) != -1)
            printf("c = <%c>, Optarg = <%s>\n",
                                       _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n",
                                    Optind, ARGV[Optind])
    }
}

Name	Size	Perms	Modified	Actions
assert.awk	383 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
bits2str.awk	334 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
cliff_rand.awk	307 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
ctime.awk	234 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
ftrans.awk	315 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
getopt.awk	2.15 KB	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
gettime.awk	2.43 KB	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
group.awk	1.72 KB	lrw-r--r--	2022-04-18 15:55:53	Edit Download recursive recursive
have_mpfr.awk	221 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
inplace.awk	1.95 KB	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
intdiv0.awk	462 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
join.awk	378 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
libintl.awk	238 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
noassign.awk	422 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
ord.awk	937 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
passwd.awk	1.17 KB	lrw-r--r--	2022-04-18 15:55:53	Edit Download recursive recursive
processarray.awk	355 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
quicksort.awk	1.01 KB	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
readable.awk	489 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
readfile.awk	267 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
rewind.awk	404 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
round.awk	661 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
shellquote.awk	472 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
strtonum.awk	1.42 KB	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
walkarray.awk	214 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive
zerofile.awk	424 B	lrw-r--r--	2018-02-25 17:17:35	Edit Download recursive recursive

Directory Contents