REDROOM

Preview: csh Size: 3.78 KB

//usr/share/Modules/init/csh

# define module command and surrounding initial environment (default value
# for MODULESHOME, MODULEPATH, LOADEDMODULES and parse of init config files)
eval "`/usr/bin/tclsh /usr/share/Modules/libexec/modulecmd.tcl csh autoinit`"

# no environment alteration if the above autoinit command failed
if ( $status == 0 ) then
   # clarify compat version is not enabled for below tests
   if ( ! $?MODULES_USE_COMPAT_VERSION ) then
      setenv MODULES_USE_COMPAT_VERSION 0
   endif

   # redefine module command if compat version has been activated
   if ( "$MODULES_USE_COMPAT_VERSION" == '1' ) then
      setenv MODULES_CMD /usr/share/Modules/libexec/modulecmd-compat ;
      if ( $?histchars && $?prompt ) alias module 'set _histchars = $histchars; unset histchars; set _prompt=$prompt:q; set prompt=""; eval `/usr/share/Modules/libexec/modulecmd-compat csh \!*`; set _exit="$status";  set histchars = $_histchars; unset _histchars; set prompt=$_prompt:q; unset _prompt; test 0 = $_exit' ;
      if ( $?histchars && ! $?prompt ) alias module 'set _histchars = $histchars; unset histchars; eval `/usr/share/Modules/libexec/modulecmd-compat csh \!*`; set _exit="$status";  set histchars = $_histchars; unset _histchars; test 0 = $_exit' ;
      if ( ! $?histchars && $?prompt ) alias module 'set _prompt=$prompt:q; set prompt=""; eval `/usr/share/Modules/libexec/modulecmd-compat csh \!*`; set _exit="$status";  set prompt=$_prompt:q;unset _prompt; test 0 = $_exit' ;
      if ( ! $?histchars && ! $?prompt ) alias module 'eval `/usr/share/Modules/libexec/modulecmd-compat csh \!*`' ;
   endif

   # define function to switch between C and Tcl versions of Modules
   set switchml_defined="`alias switchml`"
   if ( "$switchml_defined" == '' ) then
      alias switchml 'set swfound=1; \\
         if ( ! $?MODULES_USE_COMPAT_VERSION ) setenv MODULES_USE_COMPAT_VERSION 0; \\
         if ( "$MODULES_USE_COMPAT_VERSION" == "1" ) set swname="main"; \\
         if ( "$MODULES_USE_COMPAT_VERSION" == "1" && -e /usr/share/Modules/libexec/modulecmd.tcl ) set swfound=0; \\
         if ( "$MODULES_USE_COMPAT_VERSION" != "1" ) set swname="compatibility"; \\
         if ( "$MODULES_USE_COMPAT_VERSION" != "1" && -e /usr/share/Modules/libexec/modulecmd-compat ) set swfound=0; \\
         if ( $swfound == 0 && $swname == "main" ) setenv MODULES_USE_COMPAT_VERSION 0; \\
         if ( $swfound == 0 && $swname == "compatibility" ) setenv MODULES_USE_COMPAT_VERSION 1; \\
         if ( $swfound == 0 ) echo "Switching to Modules $swname version"; \\
         if ( $swfound == 0 ) source /usr/share/Modules/init/csh; \\
         if ( $swfound != 0 ) echo "Cannot switch to Modules $swname version, command not found"; \\
         unset swfound swname;'
   endif
   unset switchml_defined

   if ( $?tcsh && $?prompt && -r /usr/share/Modules/init/tcsh_completion ) then
   if ( "$MODULES_USE_COMPAT_VERSION" != '1' ) then
      source /usr/share/Modules/init/tcsh_completion
   else
      # no completion support on compat version
      uncomplete module
   endif
   endif

   if ( ":${PATH}:" !~ '*:/usr/share/Modules/bin:*' ) then
      if ( "$PATH" == '' ) then
         setenv PATH /usr/share/Modules/bin
      else
         setenv PATH "/usr/share/Modules/bin:$PATH"
      endif
   endif

   if ( $?MANPATH ) then
      set manpath = $MANPATH
   else
      set manpath = `manpath`
      # initialize MANPATH if not set with a value that preserves manpath
      # system configuration even after addition of paths to this variable
      # by modulefiles
      setenv MANPATH :
   endif
   if ( ":${manpath}:" !~ '*:/usr/share/man:*' ) then
      if ( "$MANPATH" == '' || "$MANPATH" == ':' ) then
         set mlpathsep = ''
      else
         set mlpathsep = :
      endif
      setenv MANPATH "/usr/share/man$mlpathsep$MANPATH"
      unset mlpathsep
   endif
   unset manpath
endif

Name	Size	Perms	Modified	Actions
ksh-functions DIR	-	drwxr-xr-x	2025-04-06 18:10:10	Edit Download recursive recursive
zsh-functions DIR	-	drwxr-xr-x	2025-04-06 18:10:10	Edit Download recursive recursive
bash	4.04 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
bash_completion	11.20 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
cmake	1.88 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
csh	3.78 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
fish	1.69 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
fish_completion	9.42 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
ksh	4.06 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
lisp	3.15 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
perl.pm	1.09 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
profile-compat.csh	197 B	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
profile-compat.sh	309 B	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
profile.csh	105 B	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
profile.sh	448 B	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
python.py	1.50 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
r.R	961 B	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
ruby.rb	1.35 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
sh	3.91 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
tcl	1.05 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
tcsh	3.79 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
tcsh_completion	5.39 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive
zsh	4.05 KB	lrw-r--r--	2023-10-14 18:46:13	Edit Download recursive recursive

Directory Contents