REDROOM

Create

Preview: ar-lib.m4 Size: 2.02 KB

//usr/share/aclocal-1.16/ar-lib.m4

##                                                          -*- Autoconf -*-
# Copyright (C) 2011-2018 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_PROG_AR([ACT-IF-FAIL])
# -------------------------
# Try to determine the archiver interface, and trigger the ar-lib wrapper
# if it is needed.  If the detection of archiver interface fails, run
# ACT-IF-FAIL (default is to abort configure with a proper error message).
AC_DEFUN([AM_PROG_AR],
[AC_BEFORE([$0], [LT_INIT])dnl
AC_BEFORE([$0], [AC_PROG_LIBTOOL])dnl
AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
AC_REQUIRE_AUX_FILE([ar-lib])dnl
AC_CHECK_TOOLS([AR], [ar lib "link -lib"], [false])
: ${AR=ar}

AC_CACHE_CHECK([the archiver ($AR) interface], [am_cv_ar_interface],
  [AC_LANG_PUSH([C])
   am_cv_ar_interface=ar
   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int some_variable = 0;]])],
     [am_ar_try='$AR cru libconftest.a conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
      AC_TRY_EVAL([am_ar_try])
      if test "$ac_status" -eq 0; then
        am_cv_ar_interface=ar
      else
        am_ar_try='$AR -NOLOGO -OUT:conftest.lib conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
        AC_TRY_EVAL([am_ar_try])
        if test "$ac_status" -eq 0; then
          am_cv_ar_interface=lib
        else
          am_cv_ar_interface=unknown
        fi
      fi
      rm -f conftest.lib libconftest.a
     ])
   AC_LANG_POP([C])])

case $am_cv_ar_interface in
ar)
  ;;
lib)
  # Microsoft lib, so override with the ar-lib wrapper script.
  # FIXME: It is wrong to rewrite AR.
  # But if we don't then we get into trouble of one sort or another.
  # A longer-term fix would be to have automake use am__AR in this case,
  # and then we could set am__AR="$am_aux_dir/ar-lib \$(AR)" or something
  # similar.
  AR="$am_aux_dir/ar-lib $AR"
  ;;
unknown)
  m4_default([$1],
             [AC_MSG_ERROR([could not determine $AR interface])])
  ;;
esac
AC_SUBST([AR])dnl
])

Name	Size	Perms	Modified	Actions
internal DIR	-	drwxr-xr-x	2025-04-06 18:10:11	Edit Download recursive recursive
amversion.m4	1.58 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
ar-lib.m4	2.02 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
as.m4	767 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
auxdir.m4	2.35 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
cond-if.m4	1.01 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
cond.m4	1.01 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
depend.m4	7.11 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
depout.m4	2.58 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
dmalloc.m4	906 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
extra-recurs.m4	738 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
gcj.m4	649 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
init.m4	7.84 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
install-sh.m4	681 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
lead-dot.m4	641 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
lex.m4	689 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
lispdir.m4	2.10 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
maintainer.m4	1.62 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
make.m4	1.40 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
missing.m4	1.13 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
mkdirp.m4	1.32 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
obsolete.m4	1008 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
options.m4	1.06 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
prog-cc-c-o.m4	1.65 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
python.m4	9.20 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
runlog.m4	718 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
sanity.m4	2.58 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
silent.m4	1.87 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
strip.m4	1.36 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
substnot.m4	675 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
tar.m4	4.37 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
upc.m4	836 B	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive
vala.m4	1.62 KB	lrw-r--r--	2023-10-14 20:00:43	Edit Download recursive recursive

Directory Contents