REDROOM

Navigation

Breadcrumbs

/ / usr / share / aclocal

Create

Create File | Create Folder | Upload Files | Run Command

Edit File Size: 3.60 KB

//usr/share/aclocal/lib-ld.m4

Text Base64

# lib-ld.m4 serial 6
dnl Copyright (C) 1996-2003, 2009-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl Subroutines of libtool.m4,
dnl with replacements s/_*LT_PATH/AC_LIB_PROG/ and s/lt_/acl_/ to avoid
dnl collision with libtool.m4.

dnl From libtool-2.4. Sets the variable with_gnu_ld to yes or no.
AC_DEFUN([AC_LIB_PROG_LD_GNU],
[AC_CACHE_CHECK([if the linker ($LD) is GNU ld], [acl_cv_prog_gnu_ld],
[# I'd rather use --version here, but apparently some GNU lds only accept -v.
case `$LD -v 2>&1 </dev/null` in
*GNU* | *'with BFD'*)
  acl_cv_prog_gnu_ld=yes
  ;;
*)
  acl_cv_prog_gnu_ld=no
  ;;
esac])
with_gnu_ld=$acl_cv_prog_gnu_ld
])

dnl From libtool-2.4. Sets the variable LD.
AC_DEFUN([AC_LIB_PROG_LD],
[AC_REQUIRE([AC_PROG_CC])dnl
AC_REQUIRE([AC_CANONICAL_HOST])dnl

AC_ARG_WITH([gnu-ld],
    [AS_HELP_STRING([--with-gnu-ld],
        [assume the C compiler uses GNU ld [default=no]])],
    [test "$withval" = no || with_gnu_ld=yes],
    [with_gnu_ld=no])dnl

# Prepare PATH_SEPARATOR.
# The user is always right.
if test "${PATH_SEPARATOR+set}" != set; then
  # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which
  # contains only /bin. Note that ksh looks also at the FPATH variable,
  # so we have to set that as well for the test.
  PATH_SEPARATOR=:
  (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
    && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
           || PATH_SEPARATOR=';'
       }
fi

ac_prog=ld
if test "$GCC" = yes; then
  # Check if gcc -print-prog-name=ld gives a path.
  AC_MSG_CHECKING([for ld used by $CC])
  case $host in
  *-*-mingw*)
    # gcc leaves a trailing carriage return which upsets mingw
    ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
  *)
    ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
  esac
  case $ac_prog in
    # Accept absolute paths.
    [[\\/]]* | ?:[[\\/]]*)
      re_direlt='/[[^/]][[^/]]*/\.\./'
      # Canonicalize the pathname of ld
      ac_prog=`echo "$ac_prog"| sed 's%\\\\%/%g'`
      while echo "$ac_prog" | grep "$re_direlt" > /dev/null 2>&1; do
        ac_prog=`echo $ac_prog| sed "s%$re_direlt%/%"`
      done
      test -z "$LD" && LD="$ac_prog"
      ;;
  "")
    # If it fails, then pretend we aren't using GCC.
    ac_prog=ld
    ;;
  *)
    # If it is relative, then search for the first ld in PATH.
    with_gnu_ld=unknown
    ;;
  esac
elif test "$with_gnu_ld" = yes; then
  AC_MSG_CHECKING([for GNU ld])
else
  AC_MSG_CHECKING([for non-GNU ld])
fi
AC_CACHE_VAL([acl_cv_path_LD],
[if test -z "$LD"; then
  acl_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
  for ac_dir in $PATH; do
    IFS="$acl_save_ifs"
    test -z "$ac_dir" && ac_dir=.
    if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
      acl_cv_path_LD="$ac_dir/$ac_prog"
      # Check to see if the program is GNU ld.  I'd rather use --version,
      # but apparently some variants of GNU ld only accept -v.
      # Break only if it was the GNU/non-GNU ld that we prefer.
      case `"$acl_cv_path_LD" -v 2>&1 </dev/null` in
      *GNU* | *'with BFD'*)
        test "$with_gnu_ld" != no && break
        ;;
      *)
        test "$with_gnu_ld" != yes && break
        ;;
      esac
    fi
  done
  IFS="$acl_save_ifs"
else
  acl_cv_path_LD="$LD" # Let the user override the test with a path.
fi])
LD="$acl_cv_path_LD"
if test -n "$LD"; then
  AC_MSG_RESULT([$LD])
else
  AC_MSG_RESULT([no])
fi
test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
AC_LIB_PROG_LD_GNU
])

Exit & Reset Text mode: syntax highlighting auto-detects file type.

Directory Contents

Dirs: 0 × Files: 50

Sort:

Enable drag-to-move

Name	Size	Perms	Modified	Actions
bison-i18n.m4	1.88 KB	lrw-r--r--	2019-10-12 12:28:39	Edit Download recursive recursive
codeset.m4	842 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
dovecot-pigeonhole.m4	1.85 KB	lrw-r--r--	2025-11-04 20:58:36	Edit Download recursive recursive
extern-inline.m4	4.27 KB	lrw-r--r--	2016-05-28 00:29:03	Edit Download recursive recursive
fcntl-o.m4	4.56 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
fontutil.m4	13.83 KB	lrw-r--r--	2021-10-09 23:41:50	Edit Download recursive recursive
freetype2.m4	6.18 KB	lrw-r--r--	2018-04-22 09:41:36	Edit Download recursive recursive
gettext.m4	15.49 KB	lrw-r--r--	2016-05-28 00:29:03	Edit Download recursive recursive
glibc2.m4	830 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
glibc21.m4	907 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
gpg-error.m4	4.65 KB	lrw-r--r--	2019-10-12 12:20:46	Edit Download recursive recursive
gpgrt.m4	4.61 KB	lrw-r--r--	2019-10-12 12:20:46	Edit Download recursive recursive
iconv.m4	9.06 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
intdiv0.m4	2.35 KB	lrw-r--r--	2016-05-28 00:29:03	Edit Download recursive recursive
intl.m4	11.84 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
intldir.m4	917 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
intlmacosx.m4	2.47 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
intmax.m4	1.10 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
inttypes-pri.m4	1.22 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
inttypes_h.m4	1020 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
lcmessage.m4	1.33 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
lib-ld.m4	3.60 KB	lrw-r--r--	2016-06-11 12:59:32	Edit Download recursive recursive
lib-link.m4	32.28 KB	lrw-r--r--	2016-06-11 12:59:32	Edit Download recursive recursive
lib-prefix.m4	8.27 KB	lrw-r--r--	2016-06-11 12:59:32	Edit Download recursive recursive
libgcrypt.m4	6.09 KB	lrw-r--r--	2022-06-28 11:54:07	Edit Download recursive recursive
libtool.m4	298.69 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
libxml.m4	7.70 KB	lrw-r--r--	2017-07-23 05:10:06	Edit Download recursive recursive
libxslt.m4	7.93 KB	lrw-r--r--	2009-05-12 06:29:34	Edit Download recursive recursive
lock.m4	1.43 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
longlong.m4	4.63 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
ltargz.m4	2.51 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
ltdl.m4	29.33 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
ltoptions.m4	14.17 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
ltsugar.m4	4.28 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
ltversion.m4	699 B	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
lt~obsolete.m4	6.00 KB	lrw-r--r--	2019-10-11 14:55:28	Edit Download recursive recursive
mysql.m4	4.12 KB	lrw-r--r--	2026-01-31 10:47:56	Edit Download recursive recursive
nls.m4	1.19 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
pkg.m4	12.37 KB	lrw-r--r--	2017-03-24 05:16:18	Edit Download recursive recursive
po.m4	18.52 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
printf-posix.m4	1.54 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
progtest.m4	3.02 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
size_max.m4	2.99 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
stdint_h.m4	995 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
threadlib.m4	14.80 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
uintmax_t.m4	1.09 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
visibility.m4	3.27 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
wchar_t.m4	818 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
wint_t.m4	1.03 KB	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive
xsize.m4	406 B	lrw-r--r--	2016-03-20 07:37:53	Edit Download recursive recursive